10 GOSUB 5010:REM ** CLEAR AND HOME SCREEN **
20 PRINT "========================================================================"
30 PRINT "                                 LETTER"
40 PRINT "               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
50 PRINT "    Optimized for CDP1802 based COSMAC Elf systems using RC/BASIC-L2"
60 PRINT "                        Supports VT100 terminals"
70 PRINT "========================================================================"
80 REM ** UPDATED BY: DAVE RUNKLE, 11-29-2015 **
90 PRINT
100 PRINT "LETTER GUESSING GAME"
110 PRINT
120 PRINT "I'll think of a letter of the alphabet, A TO Z."
130 PRINT "Try to guess my letter and I'll give you clues as to how close you're"
140 PRINT "getting to my letter."
150 PRINT
160 PRINT "========================================================================"
170 INPUT "HIT ENTER TO BEGIN";Z$
180 GOSUB 5010:REM ** CLEAR AND HOME SCREEN **
190 LET L=65+RND(26)
200 LET G=0
210 PRINT
220 OUT 4,L
230 PRINT "O.K., I have a letter.  Start guessing."
240 PRINT
250 INPUT "What is your guess";A$
260 LET A=ASC(A$)
270 LET G=G+1
280 PRINT
290 IF A=L GOTO 340
300 IF A>L GOTO 320
310 PRINT "TOO LOW. Try a higher letter.": GOTO 240
320 PRINT "TOO HIGH.  Try a lower letter.": GOTO 240
330 PRINT
340 PRINT "You got it in ";G;" guesses!"
350 IF G <= 5 GOTO 370
360 PRINT "BUT IT SHOULDN'T TAKE MORE THAN 5 GUESSES!":GOTO 410
370 PRINT "GOOD JOB !!!!!"
380 FOR N=1 TO 10
390 PRINT CHR$(7);
400 NEXT N
410 PRINT
420 INPUT "Try again";Z$
430 LET A$=LEFT$(Z$,1)
440 IF A$="Y" GOTO 180
450 PRINT "Thanks for playing."
460 END
5000 REM ** VT100 CONTROL ROUTINES **
5010 REM ** CLEAR SCREEN AND HOME
5020 GOSUB 5050
5030 GOSUB 5080
5040 RETURN
5050 REM ** HOME SCREEN **
5060 PRINT CHR$(27);"[H";
5070 RETURN
5080 REM ** CLEAR SCREEN **
5090 PRINT CHR$(27);"[2J";
5100 RETURN