1 REM ** UPDATED BY D.T. RUNKLE 09/23/2018**
2 PRINT CHR$(27);"[H";CHR$(27);"[2J"
5 PRINT "WELCOME TO DIGITAL EDUSYSTEM COMPUTER BLACKJACK!!":PRINT
6 PRINT "YOUR DEALER TONIGHT IS PETEY P EIGHT. WATCH HIM CLOSELY...HE HAS A REPUTATION"
7 PRINT "FOR DEALING OFF THE BOTTOM OF THE DECK.":PRINT
8 PRINT "ENTER A NUMBER BETWEEN 1 AND 100";
9 RANDOM:LET C=0
10 DIM A(13)
20 FOR I=0 TO 13 STEP 1:LET A(I)=0:NEXT I
30 PRINT "QUESTIONS REQUIRING A YES OR NO ANSWER SHOULD BE ANSWERED WITH A 'Y' FOR YES,"
40 PRINT "'N' FOR NO. DON'T START PLAYING WITH LESS THAN $100. HAVE FUN!":PRINT
50 INPUT "HOW MANY DOLLARS ARE YOU STARTING WITH";F
60 LET F1=F
70 PRINT CHR$(27);"[H";CHR$(27);"[2J"
72 IF C<45 GOTO 80
74 PRINT "OUT OF PLAYABLE CARDS...STARTING A NEW CARD DECK."
76 FOR I=0 TO 13 STEP 1:LET A(I)=0:NEXT I
78 LET C=0 
80 INPUT "WHAT IS YOUR WAGER THIS TIME";W
85 IF W>F PRINT "YOUR BET EXCEEDS YOUR REMAINING DOLLARS.":GOTO 80
90 IF W<10 PRINT "MINIMUM WAGER IS $10.":GOTO 80
100 GOSUB 780
102 LET P1=I
104 PRINT "YOUR FIRST CARD IS:  ";CHR$(L)
106 GOSUB 780
110 LET P2=I
112 PRINT "YOUR SECOND CARD IS: ";CHR$(L):PRINT
115 GOTO 200
117 PRINT "YOU HAVE ";P3;" SHOWING.":PRINT
118 INPUT "DO YOU WANT HIT";K$
119 IF K$="N" GOTO 212
120 GOSUB 780
121 LET P3=P3+I
122 PRINT "YOU GOT A ";CHR$(L):PRINT
123 IF P3>21 GOTO 820
124 GOTO 117
200 GOSUB 780
201 LET P3=P1+P2
202 LET D1=I
204 GOSUB 780
206 LET D2=I
208 PRINT "DEALER SHOWS A ";CHR$(L):PRINT
210 GOTO 117
212 LET D3=D1+D2
214 PRINT "DEALER HAS ";D3:PRINT
216 IF D3>16 GOTO 222
217 GOSUB 780
218 PRINT "DEALER GETS A ";CHR$(L):PRINT
219 LET D3=D3+I
220 GOTO 214
222 IF D3<22 GOTO 800
224 PRINT "DEALER BUSTED.":PRINT
226 GOTO 802
780 REM ** THIS ROUTINE DRAWS THE NEXT CARD **
782 LET I=RND(13)+1
784 LET A(I)=A(I)+1
786 IF A(I)>4 GOTO 782
787 LET C=C+1
788 IF I=1 LET I=11:LET L=ASC("A"):RETURN
790 IF I=13 LET I=10:LET L=ASC("K"):RETURN
792 IF I=12 LET I=10:LET L=ASC("Q"):RETURN
794 IF I=11 LET I=10:LET L=ASC("J"):RETURN
796 IF I=10 LET L=ASC("T"):RETURN
798 LET L=I+48:RETURN
800 IF D3>=P3 GOTO 820
802 LET F=F+W
806 PRINT "YOU WIN. YOU NOW HAVE $";F
808 GOTO 980
820 LET F=F-W
822 PRINT "YOU LOSE. YOU NOW HAVE $";F
824 GOTO 980
980 INPUT "DO YOU WISH TO PLAY AGAIN";K$
986 IF K$="Y" GOTO 70
987 PRINT:PRINT:PRINT:IF F>F1 GOTO 995
988 PRINT "TOO BAD! YOU LOST ";F1-F;" DOLLARS AT THE EDUSYSTEM CASINO."
990 GOTO 998
995 PRINT "NOT BAD! YOU WON";F-Fl;" DOLLARS AT THE EDUSYSTEM CASINO."
998 PRINT:PRINT "HOPE YOU ENJOYED YOURSELF. THANKS FOR PLAYING."
999 END